Показаны сообщения с ярлыком Flash. Показать все сообщения
Показаны сообщения с ярлыком Flash. Показать все сообщения

воскресенье, 18 мая 2008 г.

Изменение угла поворота камеры в Papervision

Рассмотрим пример изменения угла поворота камеры вслед за курсором мыши. За основу берем все тот же пример, с текстурой кошки, натянутой на примитив плоскости.

Первре отличие будет состоять уже в том, что пользоваться мы будем не Camera3D, а FreeCamera3D, котоая обладает нужными свойствами: rotationY и rotationX. Судя по названию, именно их изменение позволит реализовать поворот.

package
{
import flash.display.Sprite;
import flash.events.*;
import flash.filters.*;
import org.papervision3d.cameras.*;
import org.papervision3d.objects.*;
import org.papervision3d.materials.*;
import org.papervision3d.scenes.MovieScene3D;
import org.papervision3d.core.*;
import org.papervision3d.core.geom.*;

[SWF(width='400',height='400',backgroundColor='0x000000',frameRate='30')]

public class ExampleCamera extends Sprite
{
private var container: Sprite;
private var scene: MovieScene3D;
private var camera: FreeCamera3D;
private var plane:Plane;

private var mouseDown:Boolean;
private var mousePosition:Vertex3D;


public function ExampleCamera()
{
container = new Sprite;
container.x = 200;
container.y = 200;
addChild( container );

scene = new MovieScene3D( container );

camera = new FreeCamera3D();
camera.z = -500;
camera.zoom = 5;

var material:BitmapFileMaterial = new BitmapFileMaterial("texture.jpg");
plane = new Plane( material, 300, 300, 1, 1 );
scene.addChild( plane );
mouseDown = false;
mousePosition = new Vertex3D(0,0,0);
stage.addEventListener( MouseEvent.MOUSE_DOWN, mouseDownHandler );
stage.addEventListener( MouseEvent.MOUSE_UP, mouseUpHandler );
stage.addEventListener( MouseEvent.MOUSE_MOVE, mouseMoveHandler );
stage.addEventListener( Event.ENTER_FRAME, enterFrameHandler );

}

private function enterFrameHandler(event:Event):void
{
scene.renderCamera( camera );
}

private function mouseDownHandler(event:MouseEvent):void
{

mousePosition.x = event.stageX;
mousePosition.y = event.stageY;
mouseDown = true;
}

private function mouseUpHandler(event:MouseEvent):void
{
mouseDown = false;
}

private function mouseMoveHandler(event:MouseEvent):void
{
if( mouseDown )
{
camera.rotationY -= (mousePosition.x - event.stageX)*0.20;
camera.rotationX += (mousePosition.y - event.stageY)*0.20;
mousePosition.x = event.stageX;
mousePosition.y = event.stageY;
}
}


}

}

Принцип действия программы таков: по нажатию левой клавиши мыши засекается флаг mouseDown - сигнал начала поворота камеры. Если при нажатой клавише мыши происходит ее перемещение, то угол поворота камеры (rotationY и rotationX) меняется пропорционально тому, насколько был подвинут курсор.

вторник, 13 мая 2008 г.

Поиграемся с камерой

Для последующих опытов нам понадобится один из предыдущих примеров. А именно, пример с текстурой. Напомню, что в файле texture.jpg хранится изображение кота. И этот файл режит рядом с флешкой.
package
{
import flash.display.Sprite;
import flash.events.*;
import flash.utils.Timer;
import flash.filters.*;
import org.papervision3d.cameras.Camera3D;
import org.papervision3d.objects.*;
import org.papervision3d.materials.*;
import org.papervision3d.scenes.MovieScene3D;
import org.papervision3d.core.*;

[SWF(width='400',height='400',backgroundColor='0x000000',frameRate='30')]

public class ExampleTransformationRotate extends Sprite
{
private var container: Sprite;
private var scene: MovieScene3D;
private var camera: Camera3D;
private var plane:Plane;
private var myTimer:Timer = new Timer(10);

public function ExampleTransformationRotate()
{
container = new Sprite;
container.x = 200;
container.y = 200;
addChild( container );
scene = new MovieScene3D( container );
camera = new Camera3D();
camera.z = -500;
camera.zoom = 5;

var material:BitmapFileMaterial = new BitmapFileMaterial("texture.jpg");
plane = new Plane( material, 300, 300, 1, 1 );
container.filters = filter;
scene.addChild( plane );
myTimer.start();
myTimer.addEventListener(TimerEvent.TIMER, timerHandler);

}

private function timerHandler( ev:TimerEvent ): void
{
scene.renderCamera( camera );
}
}

}

После запуска сего примерчика мы вспомним, что в результате получается плоскость, на которую натянута текстура с кошачьей мордочкой. И поскольку по таймеру у нас вызывается функция, только рендерящая камеру, то плоскость к кошаком висит себе неподвижно.

Чтобы заставить камеру реагировать на перемещение мыши в последнюю функцию следует добавить метод hover, который и заменит нам приближение и повороты предмета вручную, как мы делали до этого.

private function timerHandler( ev:TimerEvent ): void
{
camera.hover(0, (200-mouseX)*.1, (200-mouseY)*.1);

scene.renderCamera( camera );
}
Попробуем разобраться, какие параметры принимает этот новый метод и как он работает. Начнем со второго, более простого вопроса. Метод hover перемещает камеру вокруг объекта, изменяя угол зрения. Перемещение может происходить (на сегодняшний день) двумя способами. Насколько я могу судить, в зависимости от первого параметра, переданного в метод. В частности, если передать 0, то камера будет совершать перемещение и по OZ тоже, тогда как в случае переданной 1 - только по OX и OY.
Два следующих параметра передают координаты точки обзора. В данном примере они находятся в зависимости от координат курсора.

Рекомендую попробовать изменить примитив на сферу или куб и посмотреть эффект.

Пока что из-за отутствия опыта я не могу судить, но мне кажется, что все же чаще придется изменять координаты камеры вручную (camera.y, camera.z, camera.x), нежели пользоваться рассмотренным методом. И тем не менее, о его существовании стоит знать.

вторник, 22 апреля 2008 г.

Эффекты с материалами.

Очередной этап состоит в изменении свойств материалов, из которых состоят примитивы, используя известные эффекты, такие как размытие, сияние и прочие. Для рассмотрения примеров будем пользоваться немножко измененным примером с плоскостью, залитую однородным красным цветом.
package
{
import flash.display.Sprite;
import flash.events.*;
import flash.utils.Timer;
import org.papervision3d.cameras.Camera3D;
import org.papervision3d.objects.*;
import org.papervision3d.materials.*;
import org.papervision3d.scenes.MovieScene3D;

[SWF(width='400',height='400',backgroundColor='0x000000',frameRate='30')]

public class ExampleTransformationRotate extends Sprite
{
private var container: Sprite;
private var scene: MovieScene3D;
private var camera: Camera3D;
private var plane:Plane;
private var myTimer:Timer = new Timer(100);

public function ExampleTransformationRotate()
{
container = new Sprite;
container.x = 200;
container.y = 200;
addChild( container );
scene = new MovieScene3D( container );
camera = new Camera3D();
camera.z = -500;
camera.zoom = 5;

var material:ColorMaterial = new ColorMaterial();
material.doubleSided = true;
material.fillColor = 0xFF0000;
material.smooth = true;
plane = new Plane( material, 300, 300, 1, 1 );
scene.addChild( plane );
myTimer.start();
myTimer.addEventListener(TimerEvent.TIMER, timerHandler);

}

private function timerHandler( ev:TimerEvent ): void
{
plane.rotationX += 5;
plane.rotationY += 2;
plane.rotationZ += 7;
scene.renderCamera( camera );

}
}
}

Этот пример немного отличается от использованного ранее. Здесь вращение плоскости осуществляется не на событие enterFrame, а по тику таймера.


  • Эффект изменения прозрачности.
    Для реализации нам понадобится изменить одно свойство материала, а именно fillAlpha. Если после подчеркнутой строки добавить material.fillAlpha = 0.1; , то вместо вращающегося ярко-красного квадратика перед нами окажется тусклый квадратик. Зачение свойства fillAlpha позволяет регулировать прозрачность заливки. Значение 0 соответствует полной прозрачности, а значение 1 - полной непрозрачности.
    Для WireframeMaterial (провоочного каркаса) эффекта можно добиться при помощи изменения пары свойств материала: material.lineColor = 0xFF0000; - отвечает за цвет каркасных линий, material.lineAlpha = 0.1; - задает их прозрачность.
    Для BitmapFileMaterial и для MovieAssetMaterial (он тоже на основе BitmapData вроде как) я пока не пойму, возможно ли изменение прозрачности заливки.
  • Эффекты с фильтрами.
    Поскольку никто не отменял использование фильтров, посмотрим, как это может улучшить результат. Для реализации, во-первых, необходимо сделать импорт соответствующей библиотеки: import flash.filters.*;. Во-вторых, в любом месте после вызова конструктора переменной container нужно сформировать набор фильтров. Например, рассмотрим эффекты сияния:

    var filter:Array = new Array();
    filter.push(new GlowFilter(0x00FF00, 0.5, 20,20, 2, BitmapFilterQuality.HIGH, false, false));
    filter.push(new GlowFilter(0x00FF00, 1, 40, 40, 2, BitmapFilterQuality.HIGH, true, false));

    Я не объясняю принцип формирования массива фильтров, считаю, что это хорошо известно и понятно написано в хелпе для Flash. После того, как массив фильтров заполнен, можно его применять: container.filters = filter;. Отличный красный квадратик с зеленым сиянием - это то, что должно было получиться. Замечу, что фильтры применяются именно к контейнеру. Такой подход работает и для WireframeMaterial, и для битмапов.

четверг, 17 апреля 2008 г.

Примитивы в Papervision

В предыдущих примерах мы рассмотрели различные материалы, натягиваемые на один и тот же графический примитив - плоскость. Оказывается, возможности этим далеко не ограничены.
Во-первых, все прообразы допустимых фигур находятся в org.papervision3d.objects. Поэтому нужно делать импорт : import org.papervision3d.objects.*.

Какие же существуют примитивы и как с ними общаться?

  • Уже знакомая нам плоскость Plane. останавливаться подробно на ней не буду, ее мы видели уже неоднократно.
  • Примитив сфера Sphere. Конструктор выглядит как new Sphere( material, 100, 8, 6). При этом первым параметром в него передается радиус сферы. Следующие два параметра определяют количество полигонов, из которых собирается сфера, по горизонтали и вертикали. Чем больше эти числа, тем более "гладкой" будет поверхность сферы.
  • Примитив куба Cube. Для него существует определенная специфика. Во-первых, вместо одного материала, для него указывается целый список, персонально для каждой грани. Например, у вас есть два материала. Material - оставшийся с прошлого раза портрет кота, material1 - просто проволочный каркас. И вы хотите сделать куб из фотографий кота, но одна сторона этого куба будет представлять собой проволочку, чтобы можно было заглянуть внутрь куба. Тогда:
    var material1:WireframeMaterial = new WireframeMaterial(0xFF0000);
    var material:BitmapFileMaterial = new BitmapFileMaterial("texture.jpg");
    material.doubleSided = true;
    material.smooth = true;
    var materiallist:MaterialsList = new MaterialsList();
    materiallist.addMaterial(material1,"top");
    materiallist.addMaterial(material,"bottom");
    materiallist.addMaterial(material,"front");
    materiallist.addMaterial(material,"back");
    materiallist.addMaterial(material,"left");
    materiallist.addMaterial(material,"right");

    И для создания самого примитива нужно вызывать конструктор new Cube( materiallist, width, depth, height, a, b, c). width, depth, height - это переменные, отвечающие соответственно за ширину, глубину и высоту куба. А a, b, c - это, как и в предыдущем случае, параметры, регулирующие количество примитивов. Попробуйте установить любой фигуре полностью проволочный каркас и поизменять эти параметры. Сразу станет ясно, какова их роль.
  • Цилиндр Cylinder. Для создания его нужно вызвать new Cylinder( material, radius, height, a, b). Radius - радиус донца цилиндра, heigth - высота фигуры, a и b - уже знакомые регуляторы числа полигонов.

На сегодняшний день это все, что мне известно о графических примитивах в ПВ. Или, по крайней мере, то, что у меня работает :)

пятница, 11 апреля 2008 г.

Материалы в Papervision: работа с внешними файлами изображений.

Для того, чтобы подгружать текстуры извне в Papervision имеется специальный класс BitmapFileMaterial. Прелесть этого материала очевидна: любой, лежащий рядом с флешкой рисунок может стать текстурой.
И нужно всего-то ничего. Изменяем материал:
var material:BitmapFileMaterial = new BitmapFileMaterial("texture.jpg");
material.doubleSided = true;
material.smooth = true;
и вот уже у меня на квадратике вращается сонная мордашка кота :)

В ПВ есть возможность в качестве материала использовать flv-видео. Я пока не сталкивалась с необходимостью это делать, но руководство на английском с примером и кодом тут.

Продолжение: материалы в PaperVision. Проблемы с Bitmap Material.

Следующим материалом, который я хотела рассмотреть, был Bitmap Material. Я честно вставляла код из туториалсов, которые нашла в вики. Но к результату это не привело.
Нужно было сделать дополнения в раздел объявления переменных:
[Embed(source="texture.jpg")]
private var File:Class;
И заменить материал:
var material:BitmapMaterial = new BitmapMaterial((new File() as Bitmap).bitmapData);
material.doubleSided = true;
material.smooth = true;
Но почему-то к какому-либо эффекту у меня это не привело. То есть ошибок нету, но в сгенерированной свф-ке просто белый экран.
Я грешу на 2 вещи:
  1. Пример писан для ПВ 1.3, а у меня уже Papervision3D Beta 1.7 (20.08.07) .
  2. Возможно, я неправильно приембедила файл с текстурой. Я его и просто рядом в каталоге клала, и в библиотеку импотрировала, и даже linkage ему давала. Ничего не помогает :(

И тогда я решила: а зачем мне битмап, если его можно засунуть в мувиклип и поступить по последнему рассмотренному примеру? Эта мысль меня крайне успокоила, и я решила продолжать дальше.

вторник, 8 апреля 2008 г.

Papervision 3d: может, познакомимся?

В связи с тем, что я "провтыкала" уже несколько работ только потому, что не хотела связываться с данным инструментом, вот, назрела необходимость.
1) Откуда взять Papervision?
Лично я брала с googleCodes. Выкачала свн-ом почти 20 мб всякой всячины вот отсюда. И положила на диск С в каталог PaperVision.
2) И что делать со всем выкачанным добром?
Дальше нужно заставить Flash IDE увидеть установленные классы. Для этого нужно ее (Flash) запустить. Создать новый документ. Зайти в Edit->Preferences->ActionScript и там нажать на кнопочку ActionScript 3.0 Settings. В появившемся окошке следует добавить путь к скачанным классам. В моем случае C:\Papervision\googlecode\as3\trunk\src . Сиреневая часть пути зависит от того, куда вы сложите скачанный код. После этой прописи Flash начнет видеть ПВ.
3) Первый пример для Papervision.
Предлагается для ознакомления на http://wiki.papervision3d.org/. В разделе Using Papervision3D -> Tutorials. Это вращающаяся плоскость красного цвета.
Для того, чтобы его посмотреть, нужно сделать следующее:

  • Создать новый Flash документ и сохранить его куда-нибудь. Помните, что благодаря прописыванию путей к классам, наш пример теперь увидит все, что нужно.
  • Создайте as-файл и сохраните его туда же под именем ExampleTransformationRotate.as
  • Во вновь созданном документе на панели Properties в поле для ввода Document Class укажите ExampleTransformationRotate. Обратите внимание, что расширение файла здесь не указывается.
  • В as-файл вставьте код:


    package

    {

    import flash.display.Sprite;
    import flash.events.Event;
    import org.papervision3d.cameras.Camera3D;
    import org.papervision3d.objects.*;
    import org.papervision3d.materials.*;
    import org.papervision3d.scenes.MovieScene3D;
    [SWF(width='400',height='400',backgroundColor='0x000000',frameRate='30')]
    public class ExampleTransformationRotate extends Sprite
    {
    private var container: Sprite;
    private var scene: MovieScene3D;
    private var camera: Camera3D;
    private var plane:Plane;
    public function ExampleTransformationRotate()
    {
    container = new Sprite;
    container.x = 200;
    container.y = 200;
    addChild( container );
    scene = new MovieScene3D( container );
    camera = new Camera3D();
    camera.z = -500; camera.zoom = 5;

    material:ColorMaterial = new ColorMaterial();
    material.doubleSided = true;
    material.fillColor = 0xFF0000;
    material.fillAlpha = 1.0;

    plane = new Plane( material, 128, 128, 1, 1 );
    scene.addChild( plane );
    stage.addEventListener( Event.ENTER_FRAME, onEnterFrame );
    }
    private function onEnterFrame( event: Event ): void
    {
    plane.rotationX += 4.35;
    plane.rotationY += 6.55;
    plane.rotationZ += 0.55;
    scene.renderCamera( camera );
    }
    }
    }
    • Сохраните as-файл.
    • Запустите свой fla-исходник.

    Крутится? Лично у меня получился вращающийся плоский красный квадратик. Правда, выкинулось в трейс cообщение:

    Papervision3D Beta RC1 (18.06.07)
    DisplayObject3D: null
    DisplayObject3D: null
    DisplayObject3D: null

    Оно осталось для меня загадкой.

    В общем, можно себя поздравить: хеллоу, ворлд, так сказать, сделан!